Library of linear IC definitions

* Library of linear IC definitions


* This is a reduced version of MicroSim's linear subcircuit library.

*   You are welcome to make as many copies of it as you find convenient.

*

* Release date: November 1988

*

* The parameters in the opamp library were derived from the data sheets for

* each part.  The macromodel used is similar to the one described in:

*

* Macromodeling of Integrated Circuit Operational Amplifiers

*   by Graeme Boyle, Barry Cohn, Donald Pederson, and James Solomon

* IEEE Journal of SoliE-State Circuits, Vol. SC-9, no. 6, Dec. 1974

*

* Differences from the reference (above) occur in the output limiting stage

* which was modified to reduce internally generated currents associated with

* output voltage limiting, as well as short-circuit current limiting.

*

* The opamps are modelled at room temperature and do not track changes with

* temperature.  This library file contains models for nominal, not worst case,

* devices.

*

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | output

*                | | | | |

.subckt LM324    1 2 3 4 5

*

  c1   11 12 2.887E-12

  c2    6  7 30.00E-12

  dc    5 53 dx

  de   54  5 dx

  dlp  90 91 dx

  dln  92 90 dx

  dp    4  3 dx

  egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5

  fb    7 99 poly(5) vb vc ve vlp vln 0 21.22E6 -20E6 20E6 20E6 -20E6

  ga    6  0 11 12 188.5E-6

  gcm   0  6 10 99 59.61E-9

  iee   3 10 dc 15.09E-6

  hlim 90  0 vlim 1K

  q1   11  2 13 qx

  q2   12  1 14 qx

  r2    6  9 100.0E3

  rc1   4 11 5.305E3

  rc2   4 12 5.305E3

  re1  13 10 1.845E3

  re2  14 10 1.845E3

  ree  10 99 13.25E6

  ro1   8  5 50

  ro2   7 99 25

  rp    3  4 9.082E3

  vb    9  0 dc 0

  vc    3 53 dc 1.500

  ve   54  4 dc 0

  vlim  7  8 dc 0

  vlp  91  0 dc 40

  vln   0 92 dc 40

.model dx D(Is=800.0E-18 Rs=1)

.model qx PNP(Is=800.0E-18 Bf=166.7)

.ends

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | output

*                | | | | |

.subckt uA741    1 2 3 4 5

*

  c1   11 12 8.661E-12

  c2    6  7 30.00E-12

  dc    5 53 dx

  de   54  5 dx

  dlp  90 91 dx

  dln  92 90 dx

  dp    4  3 dx

  egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5

  fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6

  ga    6  0 11 12 188.5E-6

  gcm   0  6 10 99 5.961E-9

  iee  10  4 dc 15.16E-6

  hlim 90  0 vlim 1K

  q1   11  2 13 qx

  q2   12  1 14 qx

  r2    6  9 100.0E3

  rc1   3 11 5.305E3

  rc2   3 12 5.305E3

  re1  13 10 1.836E3

  re2  14 10 1.836E3

  ree  10 99 13.19E6

  ro1   8  5 50

  ro2   7 99 100

  rp    3  4 18.16E3

  vb    9  0 dc 0

  vc    3 53 dc 1

  ve   54  4 dc 1

  vlim  7  8 dc 0

  vlp  91  0 dc 40

  vln   0 92 dc 40

.model dx D(Is=800.0E-18 Rs=1)

.model qx NPN(Is=800.0E-18 Bf=93.75)

.ends

*-----------------------------------------------------------------------------


*** Voltage comparators


* The parameters in this comparator library were derived from data sheets for

* each parts.  The macromodel used was developed by MicroSim Corporation, and

* is produced by the "Parts" option to PSpice.

*

* Although we do not use it, another comparator macro model is described in:

*

* An Integrated-Circuit Comparator Macromodel

*   by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch

* IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976

*

* This reference covers the considerations that go into duplicating the

* behavior of voltage comparators.

*

* The comparators are modelled at room temperature.  The macro model does not

* track changes with temperature.  This library file contains models for

* nominal, not worst case, devices.

*

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | open collector output

*                | | | | | output ground

*                | | | | | |

.subckt LM111    1 2 3 4 5 6

*

  f1    9  3 v1 1

  iee   3  7 dc 100.0E-6

  vi1  21  1 dc .45

  vi2  22  2 dc .45

  q1    9 21  7 qin

  q2    8 22  7 qin

  q3    9  8  4 qmo

  q4    8  8  4 qmi

.model qin PNP(Is=800.0E-18 Bf=833.3)

.model qmi NPN(Is=800.0E-18 Bf=1002)

.model qmo NPN(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=118.8E-9)

  e1   10  6  9  4  1

  v1   10 11 dc 0

  q5    5 11  6 qoc

.model qoc NPN(Is=800.0E-18 Bf=34.49E3 Cjc=1E-15 Tf=364.6E-12 Tr=79.34E-9)

  dp    4  3 dx

  rp    3  4 6.122E3

.model dx  D(Is=800.0E-18 Rs=1)

*

.ends

*

* End of library file


Comments

Post a Comment

Popular posts from this blog

WHAT THE WATCH TOWER BIBLE AND TRACT SOCIETY OF PENNSYLVANIA HAD TO SAY ABOUT WHAT WERE SUPPOSED TO HAVE HAPPENED in 1874

  AWAKEN                                                     Issue #33   1874 - WHAT THE WATCH TOWER BIBLE AND TRACT SOCIETY OF PENNSYLVANIA        HAD TO SAY ABOUT WHAT WERE SUPPOSED TO HAVE HAPPENED THEN.   This issue will comprise mainly of quotes from Watch Tower publications. Present day Jehovah's Witnesses are unlikely to be aware of any of this material. Why ? The Watch Tower had changed it's theology and does not bother to let it's followers know facts about the past especially since the present theology is totally contradictory to what was promoted in the past. Both sets of incompatible conjectures were promoted as being found  and proven in Scriptures. Prior to 1943 if a follower of the Watch Tower questioned any of the Watch Tower's teaching about 1874, that person risked getting kicked out of the group ...
Read more

Uninterruptable Power Source (UPS) FAQ

Article 61549 of news.answers: Xref: freenet.carleton.ca comp.misc:25723 comp.sys.hp.hardware:5708 comp.sys.sun.hardware:24796 comp.sys.sgi.hardware:9261 comp.sys.next.hardware:16000 comp.sys.dec:27561 comp.unix.admin:28511 comp.answers:8765 news.answers:33422 Path: freenet.carleton.ca!cunews!nott!bcarh189.bnr.ca!bcarh8ac.bnr.ca!bnr.co.uk!pipex!howland.reston.ans.net!news.cac.psu.edu!news.pop.psu.edu!hudson.lm.com!netline-fddi.jpl.nasa.gov!phoebe.jpl.nasa.gov!root From: ups@navigator.jpl.nasa.gov Newsgroups: comp.misc,comp.sys.hp.hardware,comp.sys.sun.hardware,comp.sys.sgi.hardware,comp.sys.next.hardware,comp.sys.ibm.hardware,comp.sys.dec,comp.unix.admin,comp.answers,news.answers Subject: Uninterruptible Power Source FAQ Followup-To: comp.misc Date: 10 Dec 1994 13:09:38 GMT Organization: Jet Propulsion Laboratory, Pasadena, CA Lines: 1346 Approved: news-answers-request@MIT.Edu Distribution: world Message-ID: <3cc9ai$fus@phoebe.jpl.nasa.gov> Reply-To: npc@minotaur.j...
Read more

Blade Runner FAQ

Archive-Name: movies/bladerunner-faq Version: 1.4 (May 1993) -------------------------------------------------------------------------------                                  BLADE RUNNER                            Frequently Asked Questions                        Copyright (C) 1993 Murray Chapman ------------------------------------------------------------------------------- Compiled by Murray Chapman (muzzle@cs.uq.oz.au), from sources too numerous to mention.  Thank-you one and all.                                INTRODUCTION                                ------------ The movie "Blade Runner"...
Read more