Library of MOSFET model parameters (for "power" MOSFET devices)

 * Library of MOSFET model parameters (for "power" MOSFET devices)

*

* This is a reduced version of MicroSim's power MOSFET model library.

*   You are welcome to make as many copies of it as you find convenient.

*

* Release date: November 1988

*

* The parameters in this model library were derived from the data sheets for

* each part.  Each part was characterize using the Parts option.

* Device can also be characterized without Parts as follows:

* LEVEL Set to 3 (short-channel device).

* TOX Determined from gate ratings.

* L, LD, W, WD Assume L=2u.  Calculate from input capacitance.

* XJ, NSUB Assume usual technology.

* IS, RD, RB Determined from "source-drain diode forward voltage"

* specification or curve (Idr vs. Vsd).

* RS Determine from Rds(on) specification.

* RDS Calculated from Idss specification or curves.

* VTO, UO, THETA Determined from "output characteristics" curve family

* (Ids vs. Vds, stepped Vgs).

* ETA, VMAX, CBS Set for null effect.

* CBD, PB, MJ Determined from "capacitance vs. Vds" curves.

* RG Calculate from rise/fall time specification or curves.

* CGSO, CGDO Determined from gate-charge, turn-on/off delay and

* rise time specifications.

*

* NOTE: when specifying the instance of a device in your circuit file:

*

* BE SURE to have the source and bulk nodes connected together, as this

* is the way the real device is constructed.

*

* DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.

* The PSpice default values for these parameters are taken into account

* in the library model statements.  Of course, you should NOT reset

* the default values using the .OPTIONS statement, either.

*

* Example use: M17 15 23 7 7 IRF150

*

* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

*

* The "power" MOSFET device models benefit from relatively complete specifi-

* cation of static and dynamic characteristics by their manufacturers.  The

* following effects are modeled:

* - DC transfer curves in forward operation,

* - gate drive characteristics and switching delay,

* - "on" resistance,

* - reverse-mode "body-diode" operation.

*

* The factors not modeled include:

* - maximum ratings (eg. high-voltage breakdown),

* - safe operating area (eg. power dissipation),

* - latch-up,

* - noise.

*

* For high-current switching applications, we advise that you include

* series inductance elements, for the source and drain, in your circuit file.

* In doing so, voltage spikes due to di/dt will be modeled.  According to the

* 1985 International Rectifier databook, the following case styles have lead

* inductance values of:

* TO-204 (modified TO-3) source = 12.5nH drain = 5.0nH

* TO-220 source =  7.5nH drain = 3.5-4.5nH

* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

*

.model IRF150 NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0

+ Tox=100n Uo=600 Phi=.6 Rs=1.624m Kp=20.53u W=.3 L=2u Vto=2.831

+         Rd=1.031m Rds=444.4K Cbd=3.229n Pb=.8 Mj=.5 Fc=.5 Cgso=9.027n

+ Cgdo=1.679n Rg=13.89 Is=194E-18 N=1 Tt=288n)

* Int'l Rectifier pid=IRFC150 case=TO3

* 88-08-25 bam creation

.model IRF9140 PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0

+ Tox=100n Uo=300 Phi=.6 Rs=70.6m Kp=10.15u W=1.9 L=2u Vto=-3.67

+ Rd=60.66m Rds=444.4K Cbd=2.141n Pb=.8 Mj=.5 Fc=.5 Cgso=877.2p

+ Cgdo=369.3p Rg=.811 Is=52.23E-18 N=2 Tt=140n)

* Int'l Rectifier  pid=IRFC9140 case=TO3

* 88-08-25 bam creation

* End of library file