Library of magnetic core model parameters

 * Library of magnetic core model parameters

* This is a reduced version of MicroSim's magnetic core library.

*   You are welcome to make as many copies of it as you find convenient.

* Release date: November 1988

* The parameters in this model library were derived from the data sheets for

* each core.  The Jiles-Atherton magnetics model is described in:

*

*   Theory of Ferromagnetic Hysteresis, by D C Jiles and D L Atherton,

*   Journal of Magnetism and Magnetic Materials, vol 61 (1986) pp 48-60

*

* Model parameters for ferrite material (Ferroxcube 3C8) were obtained by

* trial simulations, using the B-H curves from the manufacturer's catalog.

* Then, the library was compiled from the data sheets for each core geometry.

* Notice that only the geometric values change once a material is

* characterized.

* Example use:  K2 L2 .99 K1409PL_3C8

* Notes:

*   1) Using a K device (formerly only for mutual coupling) with a model

*   reference changes the meaning of the L device: the inductance value

*   becomes the number of turns for the winding.

*   2) K devices can "get away" with specifying only one inductor, as in the

*   example above, to simulate power inductors.

* Example circuit file:

*+-----------------------------------------------------------------------------

*|Demonstration of power inductor B-H curve

*|

*|* To view results with Probe (B-H curve):

*|* 1) Add Trace for B(K1)

*|* 2) set X-axis variable to H(K1)

*|*

*|* Probe x-axis unit is Oersted

*|* Probe y-axis unit is Gauss

*|*

*|.tran .1 4

*|igen0 0 1 sin(0 .1amp 1Hz 0) ; Generator: starts with 0.1 amp sinewave, then

*|igen1 0 1 sin(0 .1amp 1Hz 1) ;   +0.1 amps, starting at 1 second

*|igen2 0 1 sin(0 .2amp 1Hz 2) ;   +0.2 amps, starting at 2 seconds

*|igen3 0 1 sin(0 .8amp 1Hz 3) ;   +0.4 amps, starting at 3 seconds

*|RL 1 0 1ohm ; generator source resistance

*|L1 1 0 20 ; inductor with 20 turns

*|K1 L1 .9999 K528T500_3C8 ; Ferroxcube torroid core

*|.model K528T500_3C8 Core(MS=420E3 ALPHA=2E-5 A=26 K=18 C=1.05

*|+ AREA=1.17 PATH=8.49)

*|.options itl5=0

*|.probe

*|.end

*+-----------------------------------------------------------------------------

*** Ferroxcube pot cores: 3C8 material

.model K3019PL_3C8 Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05

+ Area=1.38 Path=4.52)

*** Ferroxcube square cores: 3C8 material

.model KRM8PL_3C8 Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05

+ Area=.630 Path=3.84)

*** Ferroxcube toroid cores: 3C8 material

.model K502T300_3C8 Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05

+ Area=.371 Path=7.32)

*** end of library file