Library of linear IC definitions

* Library of linear IC definitions


* This is a reduced version of MicroSim's linear subcircuit library.

*   You are welcome to make as many copies of it as you find convenient.

*

* Release date: November 1988

*

* The parameters in the opamp library were derived from the data sheets for

* each part.  The macromodel used is similar to the one described in:

*

* Macromodeling of Integrated Circuit Operational Amplifiers

*   by Graeme Boyle, Barry Cohn, Donald Pederson, and James Solomon

* IEEE Journal of SoliE-State Circuits, Vol. SC-9, no. 6, Dec. 1974

*

* Differences from the reference (above) occur in the output limiting stage

* which was modified to reduce internally generated currents associated with

* output voltage limiting, as well as short-circuit current limiting.

*

* The opamps are modelled at room temperature and do not track changes with

* temperature.  This library file contains models for nominal, not worst case,

* devices.

*

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | output

*                | | | | |

.subckt LM324    1 2 3 4 5

*

  c1   11 12 2.887E-12

  c2    6  7 30.00E-12

  dc    5 53 dx

  de   54  5 dx

  dlp  90 91 dx

  dln  92 90 dx

  dp    4  3 dx

  egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5

  fb    7 99 poly(5) vb vc ve vlp vln 0 21.22E6 -20E6 20E6 20E6 -20E6

  ga    6  0 11 12 188.5E-6

  gcm   0  6 10 99 59.61E-9

  iee   3 10 dc 15.09E-6

  hlim 90  0 vlim 1K

  q1   11  2 13 qx

  q2   12  1 14 qx

  r2    6  9 100.0E3

  rc1   4 11 5.305E3

  rc2   4 12 5.305E3

  re1  13 10 1.845E3

  re2  14 10 1.845E3

  ree  10 99 13.25E6

  ro1   8  5 50

  ro2   7 99 25

  rp    3  4 9.082E3

  vb    9  0 dc 0

  vc    3 53 dc 1.500

  ve   54  4 dc 0

  vlim  7  8 dc 0

  vlp  91  0 dc 40

  vln   0 92 dc 40

.model dx D(Is=800.0E-18 Rs=1)

.model qx PNP(Is=800.0E-18 Bf=166.7)

.ends

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | output

*                | | | | |

.subckt uA741    1 2 3 4 5

*

  c1   11 12 8.661E-12

  c2    6  7 30.00E-12

  dc    5 53 dx

  de   54  5 dx

  dlp  90 91 dx

  dln  92 90 dx

  dp    4  3 dx

  egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5

  fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6

  ga    6  0 11 12 188.5E-6

  gcm   0  6 10 99 5.961E-9

  iee  10  4 dc 15.16E-6

  hlim 90  0 vlim 1K

  q1   11  2 13 qx

  q2   12  1 14 qx

  r2    6  9 100.0E3

  rc1   3 11 5.305E3

  rc2   3 12 5.305E3

  re1  13 10 1.836E3

  re2  14 10 1.836E3

  ree  10 99 13.19E6

  ro1   8  5 50

  ro2   7 99 100

  rp    3  4 18.16E3

  vb    9  0 dc 0

  vc    3 53 dc 1

  ve   54  4 dc 1

  vlim  7  8 dc 0

  vlp  91  0 dc 40

  vln   0 92 dc 40

.model dx D(Is=800.0E-18 Rs=1)

.model qx NPN(Is=800.0E-18 Bf=93.75)

.ends

*-----------------------------------------------------------------------------


*** Voltage comparators


* The parameters in this comparator library were derived from data sheets for

* each parts.  The macromodel used was developed by MicroSim Corporation, and

* is produced by the "Parts" option to PSpice.

*

* Although we do not use it, another comparator macro model is described in:

*

* An Integrated-Circuit Comparator Macromodel

*   by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch

* IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976

*

* This reference covers the considerations that go into duplicating the

* behavior of voltage comparators.

*

* The comparators are modelled at room temperature.  The macro model does not

* track changes with temperature.  This library file contains models for

* nominal, not worst case, devices.

*

*-----------------------------------------------------------------------------

* connections:   non-inverting input

*                | inverting input

*                | | positive power supply

*                | | | negative power supply

*                | | | | open collector output

*                | | | | | output ground

*                | | | | | |

.subckt LM111    1 2 3 4 5 6

*

  f1    9  3 v1 1

  iee   3  7 dc 100.0E-6

  vi1  21  1 dc .45

  vi2  22  2 dc .45

  q1    9 21  7 qin

  q2    8 22  7 qin

  q3    9  8  4 qmo

  q4    8  8  4 qmi

.model qin PNP(Is=800.0E-18 Bf=833.3)

.model qmi NPN(Is=800.0E-18 Bf=1002)

.model qmo NPN(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=118.8E-9)

  e1   10  6  9  4  1

  v1   10 11 dc 0

  q5    5 11  6 qoc

.model qoc NPN(Is=800.0E-18 Bf=34.49E3 Cjc=1E-15 Tf=364.6E-12 Tr=79.34E-9)

  dp    4  3 dx

  rp    3  4 6.122E3

.model dx  D(Is=800.0E-18 Rs=1)

*

.ends

*

* End of library file


Comments

Post a Comment

Popular posts from this blog

PHILEMON

PHILEMON 1:1 Paul, a prisoner of Jesus Christ, and Timothy {our} brother, unto Philemon our dearly beloved, and fellowlabourer, PHILEMON 1:2 And to {our} beloved Apphia, and Archippus our fellowsoldier, and to the church in thy house: PHILEMON 1:3 Grace to you, and peace, from God our Father and the Lord Jesus Christ. PHILEMON 1:4 I thank my God, making mention of thee always in my prayers, PHILEMON 1:5 Hearing of thy love and faith, which thou hast toward the Lord Jesus, and toward all saints; PHILEMON 1:6 That the communication of thy faith may become effectual by the acknowledging of every good thing which is in you in Christ Jesus. PHILEMON 1:7 For we have great joy and consolation in thy love, because the bowels of the saints are refreshed by thee, brother. PHILEMON 1:8 Wherefore, though I might be much bold in Christ to enjoin thee that which is convenient, PHILEMON 1:9 Yet for love's sake I rather beseech {thee}, being such an one as Paul the aged, and now ...
Read more

War of the World TV series

EDITOR'S NOTE: I have only compiled this list.  I claim no responsibility for errors, discrepensies, bogus entries, repeated or contradictiory entries, spelling or grammatical errors, or governmental action against those in possession of this list. Thank for for your support! THE PREMISE: Last year, I attended a Science Fiction convention during which I discovered (along with other things) that the makers of the recently-demised TV series War of the Worlds, had a scene in the very first episode, where the original Martian war machines were found mouldering in a LA warehouse.  For fun, the special effects folk labeled one of the boxes in the warehouse 'Ark of the Covenant', indicating that it was the SAME warehouse where the Govt.  hid everything that folks were not to know about.  Recently, I decided to try to use this warehouse in a role-playing game, for fun.  I've been trying to figure out things that should be in some of the boxes.  I'...
Read more