The Official Way to Software Reboot an Amiga

      The Official Way to Software Reboot an Amiga - Bryce Nesbitt

* Copyright 1988 Commodore-Amiga, Inc.

*  

* Executables based on this information may be used in software

* for Commodore Amiga computers.  All other rights reserved.

* This information is provided "as is"; no warranties are made.  All 

* use is at your own risk. No liability or responsibility is assumed.



A number of Amiga programmers have had the need to reboot the machine

from within a program.  Since no official guidelines have ever been

published, programmers have used various creative methods.


Unfortunately rebooting the machine is very tricky, and most attempts

have been flawed.  The RESET instruction, for example, unconfigures

all memory; after RESET there is no place to run user code!

Most reboot code will break whenever the memory or CPU configuration

is changed.  Other reset code will not work properly on the Amiga 1000.

A special sequence of operations is required to work with all the possible

memory and processor options available for the Amiga.


What follows is the one-and-only official supported way to reboot an Amiga

under software control.




****************************************************************************

*

*   NAME

*       ColdReboot - reboot the Amiga

*

*   SYNOPSIS

*       ColdReboot()

*

*       void ColdReboot(void);

*

*   FUNCTION

*       Reboot the machine.  All external memory and peripherals will be

*       RESET, and the machine will start its power up diagnostics.

*

*       The MagicResetCode must be used exactly as specified here.

*       The MagicResetCode must be longword aligned.  Failure to

*       duplicate the code EXACTLY will result in improper operation

*       under certain system configurations.

*

*   RESULT

*       This function never returns.

*

****************************************************************************

                XDEF    _ColdReboot


                XREF    _LVOSupervisor


_ColdReboot:

                move.l  4,a6                    ;Get a pointer to ExecBase

                lea.l   MagicResetCode(pc),a5   ;Location of code to RUN

                jsr     _LVOSupervisor(a6)      ;RUN code in Supervisor mode

        ;[NOTE: The jsr is required even though Supervisor never returns.]


;-------------- MagicResetCode ---------DO NOT CHANGE-----------------------

                CNOP    0,4     ;IMPORTANT!  Longword align!  Do not change!

MagicResetCode:

                lea.l   2,a0    ;Point to JMP instruction at start of ROM

                RESET           ;all RAM goes away now!

                jmp     (a0)    ;Rely on prefetch to execute this instruction

;---------------------------------------DO NOT CHANGE----------------------- 


                END




Comments

Post a Comment

Popular posts from this blog

BOTTOM LIVE script

                                  BOTTOM                                   ======                     by Adrian Edmondson and Rik Mayall                                 Bottom Live                                 ===========                               Richie  Rik Mayall                                Eddie  Adrian Edmondson Introduction ------------ [Opening shot of theatre, with huge pictures of Richie and Eddie. Caption: "Live fro...
Read more

Evidence supporting quantum information processing in animals

              Evidence supporting quantum            information processing in animals                    James A. Donald                    1068 Fulton Av                    Sunnyvale, CA 94089-1505                    USA I show that quantum systems can rapidly solve some problems for which finite state machines require a non- polynomially large time. This class of problems is closely related to the class of problems that animals can solve rapidly and effortlessly, but are intractable for computers by all known algorithms. 1. Introduction      Animals, including very simple animals, can rapidly and effortlessly perceive objects, whereas computers take nonpolynomial time to do this by all...
Read more

ARMIES OF CHAOS

                          ARMIES OF CHAOS -      Before anyone proposes more gun control, he or she should know  about a simple, deadly weapon 4 times as powerful as Dirty Harry's  legendary .44 Magnum -- and at least twice as concealable -- that  _can't_ controlled.        This simple, deadly weapon can be made by anyone -- even a  child -- with unpowered hand tools in an hour's time using $5 worth  of materials, most of which are available around the house anyway.   In traditional form it's reusable an unlimited number of times, and  modern plastics have rendered its disposable version electronically  undetectable.  You can clear a room with such a weapon (more of a  hand-held directional grenade than a gun -- sort of a recycleable  Claymore mine) and it's just one of hundreds of similar time-proven  designs. ...
Read more